Add a test case for the database corruption in the form of cell offsets

out of range in an otherwise valid btree page. (CVS 5202)

FossilOrigin-Name: c569a6cf664e9a8095f616327719392fb8186d37

test/corrupt7.test

@@ -0,0 +1,75 @@
+# 2008 June 11
+#
+# The author disclaims copyright to this source code.  In place of
+# a legal notice, here is a blessing:
+#
+#    May you do good and not evil.
+#    May you find forgiveness for yourself and forgive others.
+#    May you share freely, never taking more than you give.
+#
+#***********************************************************************
+# This file implements regression tests for SQLite library.
+#
+# This file implements tests to make sure SQLite does not crash or
+# segfault if it sees a corrupt database file.  It specifically focuses
+# on corrupt cell offsets in a btree page.
+#
+# $Id: corrupt7.test,v 1.1 2008/06/11 18:01:22 drh Exp $
+
+set testdir [file dirname $argv0]
+source $testdir/tester.tcl
+
+# We must have the page_size pragma for these tests to work.
+#
+ifcapable !pager_pragmas {
+  finish_test
+  return
+}
+
+# Create a simple, small database.
+#
+do_test corrupt7-1.1 {
+  execsql {
+    PRAGMA auto_vacuum=OFF;
+    PRAGMA page_size=1024;
+    CREATE TABLE t1(x);
+    INSERT INTO t1(x) VALUES(1);
+    INSERT INTO t1(x) VALUES(2);
+    INSERT INTO t1(x) SELECT x+2 FROM t1;
+    INSERT INTO t1(x) SELECT x+4 FROM t1;
+    INSERT INTO t1(x) SELECT x+8 FROM t1;
+  }
+  file size test.db
+} [expr {1024*2}]
+
+# Verify that the file format is as we expect.  The page size
+# should be 1024 bytes.
+#
+do_test corrupt7-1.2 {
+  hexio_get_int [hexio_read test.db 16 2]
+} 1024   ;# The page size is 1024
+do_test corrupt7-1.3 {
+  hexio_get_int [hexio_read test.db 20 1]
+} 0      ;# Unused bytes per page is 0
+
+integrity_check corrupt7-1.4
+
+# Deliberately corrupt some of the cell offsets in the btree page
+# on page 2 of the database.
+#
+do_test corrupt7-2.1 {
+  db close
+  hexio_write test.db 1062 FF
+  sqlite3 db test.db
+  db eval {PRAGMA integrity_check(1)}
+} {{*** in database main ***
+Corruption detected in cell 15 on page 2}}
+do_test corrupt7-2.2 {
+  db close
+  hexio_write test.db 1062 04
+  sqlite3 db test.db
+  db eval {PRAGMA integrity_check(1)}
+} {{*** in database main ***
+Corruption detected in cell 15 on page 2}}
+
+finish_test